/*
  Magischer Wuerfel der Ordnung 3
  Copyright (c) 1998 by Jan Theofel und Martin Trautmann
*/


#include "colors.inc"

camera {
  location <4, -0.7, -4>
  look_at <1.5, 1.5, 1.5>
}

light_source { <6, -3, -5> colour White }
light_source { <-2, -3, -5> colour White }
light_source { <2, 7, -3> colour White }
light_source { <6, 2, 3> colour White }
light_source {
  <0, 1, -3>
  colour White
  spotlight
  point_at<1.5,1.5,0>
  radius 5
}

background { color Black }

#declare n = 3

#declare glas = texture {
   pigment {
     granite
     color_map {
       [ 0.000  color rgbf<0.916, 0.682, 0.567, 0.9> ]
       [ 1.000  color rgbf<1.000, 1.000, 1.000, 0.9> ]
     }
     turbulence 0.200
   }
   finish {
     diffuse 0.00
     ambient 1.00
     reflection 0.000
     refraction 1
     ior 1.50
     specular 0.1
     roughness 0.0010
   }
}

box{
  <0,0,0>,
  <n,n,n>
  texture{glas}
}

#declare w=0
#while (w<(n+1)*(n+1))
  cylinder{
    <div(w,n+1), 0,mod(w,n+1)>,<div(w,n+1),n,mod(w,n+1)>,0.02
    pigment { colour Gray70 }
  }
  #declare w=w+1
#end

#declare w=0
#while (w<(n+1)*(n+1))
  cylinder{
    <0,div(w,n+1), mod(w,n+1)>,<n,div(w,n+1),mod(w,n+1)>,0.02
    pigment { colour Gray70 }
  }
  #declare w=w+1
#end

#declare w=0
#while (w<(n+1)*(n+1))
  cylinder{
    <div(w,n+1),mod(w,n+1),0>,<div(w,n+1),mod(w,n+1),n>,0.02
    pigment { colour Gray70 }
  }
  #declare w=w+1
#end

#declare R1=seed(5000)
#declare T=texture{
   finish {
      ambient 0.6
      diffuse 0.8
      phong 0.6
      phong_size 100
      }
   }

#declare posx1=1
#declare posx2=0
#declare posx3=1

#declare m1x1=1
#declare m1x2=1
#declare m1x3=0

#declare m2x1=2
#declare m2x2=0
#declare m2x3=2

#declare m3x1=0
#declare m3x2=2
#declare m3x3=2

#declare w=0

#while (w<n*n*n)
  #declare x1=mod(posx1+m1x1*mod(w,n)+m2x1*mod(div(w,n),n)+m3x1*div(w,n*n),n)
  #declare x2=mod(posx2+m1x2*mod(w,n)+m2x2*mod(div(w,n),n)+m3x2*div(w,n*n),n)
  #declare x3=mod(posx3+m1x3*mod(w,n)+m2x3*mod(div(w,n),n)+m3x3*div(w,n*n),n)
  #declare w=w+1
  #declare tzahl=str(w,2,0)
  text {
    ttf "crystal.ttf",
    tzahl,0.3,0
    texture{T}
    pigment { color White }
    scale <0.4,0.4,0.4>
    translate <x1+0.3,x2+0.3,x3+0.3>
  }
#end